Optimizarea secţiunilor unei structuri din bare pentru reducerea ...

Lab. 9. Optimizarea secŃiunilor unei structuri din bare pentru
reducerea greutăŃii proprii cu respectarea condiŃiilor de stabilitate şi
asigurarea rigidităŃii dinamice. Prezentarea modelului parametric şi
analiza demonstrativă în sprijinul temei de proiectare
AplicaŃie rezolvată
Se consideră grinda cu zăbrele static determinată din Fig. 9.1. Să se determine înălŃimile H 1 ,
H 2 şi H 3 şi ariile secŃiunilor celor 11 bare în condiŃia minimizării greutăŃii proprii a structurii. Se
consideră L = 1 m; F = 10 kN; E = 200 GPa; ρ = 7850 kg/m 3 şi σ
a
= 150 MPa. Pentru soluŃia
optimă găsită se cere:
-dimensionarea inelară a tuturor secŃiunilor (diametrul exterior şi grosimea peretelui de
Ńeavă) astfel încât coeficientul de siguranŃă la flambaj pentru toate barele comprimate să fie c
f
≥ 2 ;
-deplasarea verticală a capătului liber;
-primele 10 frecvenŃe proprii în ipoteza că toate forŃele aplicate corespund unor mase
concentrate în nodurile respective;
-dezvoltarea unui model de Ńevi sudate (pentru proiectarea optimală) şi compararea
rezultatelor obŃinute din acest model cu modelul iniŃial de bare articulate;
-discuŃii legate de optimizare şi condiŃiile restrictive pentru diametrele optime ale Ńevilor,
modurile de îmbinare dintre Ńevi, precum şi rezultatele numerice obŃinute.
Fig. 9.1: Grindă cu zăbrele static determinată
1. Rezolvare analitică
Se consideră numerotarea nodurilor şi a elementelor din Fig. 9.2. Din echilibrul
structurii rezultă reacŃiunile (vezi Fig. 9.2)
9FL
RH
= ; RV
= 6F
.
H
1

Fig. 9.2: Discretizarea modelului structurii
Deoarece structura este static determinată, eforturile în bare se pot determina numai din
condiŃiile de echilibru nodal. Tensiunile în bare pot fi egale cu ± σ , adică materialul este utilizat
optim dacă ariile barelor se determină din condiŃia
A
N
i
i
= . σ
a
Eforturile din bare, introduse la noduri, se consideră pozitive dacă sunt orientate de-a lungul
barelor (Fig. 9.3). Pentru obŃinerea eforturilor sunt necesare ecuaŃiile de echilibru nodal numai
pentru oricare n-1=6 noduri.
a
scrie:
Fig. 9.3: ForŃele nodale obŃinute prin izolarea nodurilor
La calculul forŃelor nodale intervin unghiurile α, β , γ , δ din Fig. 9.3, pentru care se poate
sinα =
cos β =
cosδ =
L
H
3
+ H
2 2
3
L
;
( ) 2
2
L + H2 − H3
L
( ) 2
2
L + H1 − H
2
cosα =
L
L
+ H
2 2
3
2
; sinγ =
2 2
L + H
2
Din izolarea nodului 1, relaŃiile de echilibru conduc la
2 2
L
L + H3
N1
= − F ; N2
= F .
H
3
H3
Din izolarea nodului 2, relaŃiile de echilibru conduc la
L
N
3
= 0 ; N4
= − F . H
.
3
;
H
2
sin β =
;
H
− H
2 3
( )
2
L + H
2
− H3
cosγ =
L
L
+ H
2
2 2
2
;
;

Din izolarea nodului 5, relaŃiile de echilibru conduc la
2 2 4 1
N5 F L H ⎛
2
⎞
L + H2 − H2
= − +
3 ⎜ − ⎟ ; N6
= 4F
.
⎝ H
2 H
3 ⎠
H3
Din izolarea nodului 3, relaŃiile de echilibru conduc la
⎛ 4H
⎞
3
L
N7
= F ⎜ −1⎟
; N8
= − 4F .
⎝ H
2 ⎠
H
2
Din izolarea nodului 4, relaŃiile de echilibru conduc la
2 2 9 4
N9 F L H ⎛ ⎞
⎛ 9H
⎞
2
= − +
2 ⎜ − ⎟ ; N11
= −F
⎜10
− ⎟ .
⎝ H
1 H
2 ⎠
⎝ H1
⎠
Din izolarea nodului 7, relaŃiile de echilibru conduc la
N
10
= 9F
( ) 2
2
L + H1 − H
2
3
( ) 2
H1
Elementele geometrice care definesc barele şi eforturile din acestea sunt sistematizate în
Tabelul de mai jos.
Elem Lungimea Efortul: Întindere-
Compresiune
1 L
2 2 2
L + H 3
3
3
4 L
5 2 2
L H 3
6
F
L
− F
H
L
3
+ H
2 2
3
H
3
σ
a
σ
a
Aria necesară× Volumul ×
F
F
L
2
L
H
3
H
L
+ H
2 2
3
H
3
3
L + H
H
H 0 0 0
L
− F H
⎛ 4 1 ⎞
− F L + H ⎜ − ⎟
⎝ H
2 H
3 ⎠
+ 2 2
3
3
L
H
⎛
2 2
L + H3
⎜ − H
2 H
3
⎝
3
4 1
⎞
⎟
⎠
( L
2 H
2
3 )
2 2
3
L
H
2
3
3
⎛ 4 1 ⎞
+ ⎜ − ⎟
⎝ H
2
H3
⎠
+ ( − ) 2
L 2 + ( H − H ) 2
2
+ ( − ) 2
2
+ ( ) 2
2
−
2
2
L H
2
H3
7 H
2
8 L
9 2 2
L H 2
10
4F
H
2 2
3
⎛ 4H
⎞
3
F ⎜ −1⎟
⎝ H
2 ⎠
L
− 4F H
⎛ 9 4 ⎞
− F L + H ⎜ − ⎟
⎝ H
1 H
2 ⎠
+ 2 2
2
2
2 2
4 L H H
H
2
3
4 L H H
H
4H3
1
H − 4H3 − H2
4 L H 2
⎛
9 4
2 2
L + H
2 ⎜ − H
1 H
2
⎝
⎞
⎟
⎠
( L
2 H
2
2 )
2
3
4 L H 2
⎛ 9 4 ⎞
+ ⎜ − ⎟
⎝ H1 H
2 ⎠
+ ( − ) 2
L 2 + ( H − H ) 2
2
+ ( − ) 2
2
+ ( ) 2
1
−
2
2
L H1 H
2
11 H
1
9F
H
1 2
⎛ 9H
⎞
2
−F
⎜10
− ⎟
⎝ H1
⎠
ObservaŃii:
1. Pentru a obŃine volum pozitiv se impun restricŃiile:
4H3 > H
2
; 9H
2
> 4H1
; 10H1 > 9H2
.
1
1 2
9 L H H
H
10
1
9H
H
9 L H H
H
2
1 2
−
1
1
10H
− 9H

2. Bara 3 este nesolicitată, în realitate aria ei nu poate fi nulă (adică bara nu poate lipsi)
deoarece structura se transformă în mecanism. În calculele care urmează aceasta nu este introdusă
deşi în realitate trebuie considerată o bară cu arie mult mai mică decât a celorlalte elemente.
Din ultima coloană a tabelului de mai sus se obŃine volumul total al structurii funcŃie numai
de parametri constanŃi de intrare şi de parametrii de proiectare H 1 , H 2 şi H 3 :
2 2 2 2 2
F ⎡
L H
2
L H3
L ⎤
V = ⎢19H 1
− 28H 2
− 4H3
+ 18 + 18 + 8 + 8 + 2 ⎥ .
σ
a ⎣
H1 H1 H2 H2 H3
⎦
Din condiŃia de minim a funcŃiei de volum total
∂V
∂V
∂V
= 0 ; = 0;
= 0 ,
∂H1
∂H2
∂H3
rezultă sistemul neliniar de ecuaŃii
2 2 2
⎧ 19H1 − 18H 2
= 18L
⎪ 2 2 2 3
⎨7H1H 2
+ 2H1H3 + 2L H1 − 9H
2
= 0 .
⎪ 2 2 3
⎩ 2H2H3 + L H
2
− 8H3
= 0
Rezolvarea sistemului de mai sus (prin substituŃie directă şi rezolvarea neliniară a unei
ecuaŃii cu o singură variabilă în H 3 utilizând mediul MATLAB – vezi fzero.m) conduce la
H1 = 1,9746 L;
H2 = 1,7651L
;
H3 = 0,7925L
.
Pentru rezolvarea acestui sistem de ecuaŃii neliniare în Matlab se creează fişierul text
f_opt.m care conŃine liniile:
function y=f_opt(H3)
% functie de o variabila utilizata pentru rezolvarea unei ecuatii neliniare
a=1000^2;
H2=(8*H3.^3)./(2*H3.^2+a);
H1=sqrt(18/19*(a+H2.^2));
y=(7*H2.^2+2*H3.^2+2*a)*H1-9*H2.^3;
apoi în mediul de programare Matlab se execută secvenŃa de comenzi:
» H3=fzero('f_opt',500) % H3 = 792.5347
» H2=8*H3^3/(2*H3^2+1000^2) % H2 = 1.7651e+003
» H1=sqrt(18/19*(1000^2+H2^2)) % H1 = 1.9746e+003
Pentru a verifica că soluŃia precizată este un punct de minim se poate determina matricea
Hesiană în punctul care a fost obŃinut extremul şi apoi se poate verifica că această matrice este
pozitiv definită. Prin înlocuirea valorilor numerice din tabelul de mai sus, rezultă
Bara ForŃele axiale
[N]
Ariile secŃiunilor
[mm 2 ]
Tensiunile în bare
[MPa]
Volumele elementelor
[cm 3 ]
1 -12626 84.1733 -150 84.1750
2 16107 107.3800 150 136.9800
3 0 0 0 0.0000
4 -12626 84.1733 -150 84.1750
5 -12803 85.3533 -150 108.8800
6 31620 210.8000 150 294.1200
7 7949 52.9933 150 93.5330
8 -22663 151.0867 -150 151.0900
9 -46469 309.7933 -150 628.4400
10 46564 310.4267 150 317.1900
11 -19570 130.4667 -150 257.6700
Total 2156.25
Masa structurii, fără bara 3, rezultă MASA_STR = 16.9265894 kg.
4

2. Optimizare fără model cu elemente finite
Dacă se creează fişierul de comenzi ANSYS COM_SS.txt şi se salvează în directorul curent
(de lucru) astfel:
! GRINDA CU ZABRELE IN CONSOLA STATIC DETERMINATA
! OPTIMIZARE PENTRU VOLUM MINIM(H1 H2 SI H3) Stefan SOROHAN
!*
F=10000 ! IN N
L=1000 ! IN MM
S_A=150 ! TENSIUNEA ADMISIBILA
E=2E5 ! MODULUL DE ELASTICITATE
ro=7850E-9 ! DENSITATEA kg/mm^3
!*
/PREP7
! PARAMETRI CARE SE OPTIMIZEAZA
H1=1200
H2=1200
H3=1200
! FORTELE (EFORTURILE) DIN BARE DETERMINATE ANALITIC
N1=-F*L/H3
N2=F*SQRT(L**2+H3**2)/H3
N3=0
N4=N1
N5=-F*SQRT(L**2+H3**2)*(4/H2-1/H3)
N6=4*F*SQRT(L**2+(H2-H3)**2)/H2
N7=F*(4*H3/H2-1)
N8=-4*F*L/H2
N9=-F*SQRT(L**2+H2**2)*(9/H1-4/H2)
N10=9*F*SQRT(L**2+(H1-H2)**2)/H1
N11=-F*(10-9*H2/H1)
!*
! VOLUMUL ELEMENTELOR DETERMINAT ANALITIC
! OBS: DEOARECE EXPRESIA ESTE PREA LUNGA S-AU CONSIDERAT 4 TERMENI
VOL1=19*H1-28*H2-4*H3
VOL2=18/H1*L**2+18/H1*H2**2
VOL3=8/H2*L**2+8/H2*H3**2
VOL4=2/H3*L**2
VOL_TOT=F/S_A*(VOL1+VOL2+VOL3+VOL4) ! VOLUMUL TOTAL, FARA BARA 3
MASA_STR=ro*VOL_TOT ! IN kg
! PARAMETRI ADITIONALI SE STERG
VOL1=
VOL2=
VOL3=
VOL4=
FINISH
atunci cu metoda de optimizare “First Order”, în care secvenŃa de comenzi care definesc parametrii
de optimizare, funcŃia obiectiv şi lansarea în execuŃie sunt precizaŃi în liniile de comenzi de mai jos
se pot obŃine valorile optime pentru cele trei înălŃimi care definesc parametrii de proiectare.
/OPT
OPANL,'COM_SS','txt',' '
OPVAR,H1,DV,500,2500,1, ! LIMITA MIN-MAX SI TOLERANTA
OPVAR,H2,DV,500,2500,1,
OPVAR,H3,DV,500,2500,1,
!*
OPVAR,MASA_STR,OBJ, , ,0.001, ! TOLERANTA 0.001
!*
OPTYPE,FIRS
OPFRST,10, , ,
!*
OPEXE
ObservaŃie: Aceste ultime comenzi se pot executa şi în modul de lucru GUI. Rezultatele
analizei se pot urmări în secvenŃa de seturi obŃinute:
SET 1 SET 2 SET 3 SET 4
(FEASIBLE) (FEASIBLE) (FEASIBLE) (FEASIBLE)
H1 (DV) 1200.0 1763.6 1757.6 1905.6
5

H2 (DV) 1200.0 1469.5 1598.2 1710.8
H3 (DV) 1200.0 673.77 690.61 821.69
MASA_STR(OBJ) 20.375 17.164 17.046 16.944
SET 5 *SET 6* SET 7
(FEASIBLE) (FEASIBLE) (FEASIBLE)
H1 (DV) 1971.1 1967.6 1969.8
H2 (DV) 1751.6 1761.4 1755.1
H3 (DV) 788.78 785.88 789.90
MASA_STR(OBJ) 16.927 16.927 16.927
Dacă se trasează graficele variaŃiei parametrilor funcŃie de seturile obŃinute în algoritmul de
optimizare (Fig. 9.4 – Fig. 9.6) se observă că metoda de optimizare aleasă converge uniform către
soluŃia obŃinută pe cale analitică. Din cauza toleranŃei funcŃiei obiectiv 0.001, algoritmul se opreşte
înainte de a atinge valorile teoretice mult mai exact determinate.
Fig. 9.4: VariaŃia funcŃiei obiectiv în funcŃie de numărul iteraŃiei pentru metoda “First Order”
Fig. 9.5: VariaŃia variabilelor de proiectare în funcŃie de numărul iteraŃiei pentru metoda “First Order”
6

Fig. 9.6: VariaŃia eforturilor în bare în funcŃie de numărul iteraŃiei pentru metoda “First Order”
Cu metoda de optimizare “Subproblem Aproximation” în care secvenŃa de comenzi care
definesc parametrii de optimizare, funcŃia obiectiv şi lansarea în execuŃie sunt:
/OPT
OPANL,'COM_SS','txt',' '
OPVAR,H1,DV,500,2500,1, ! LIMITA MIN-MAX SI TOLERANTA
OPVAR,H2,DV,500,2500,1,
OPVAR,H3,DV,500,2500,1,
!*
OPVAR,MASA_STR,OBJ, , ,0.001, ! TOLERANTA 0.001
!*
OPTYPE,SUBP
OPSUBP,30,7,
OPEQN,0,0,0,0,0,
!*
!*
OPEXE
se obŃine secvenŃa de seturi:
SET 1 SET 2 SET 3 SET 4
(FEASIBLE) (FEASIBLE) (FEASIBLE) (FEASIBLE)
H1 (DV) 1200.0 2194.3 1884.7 2195.7
H2 (DV) 1200.0 1414.4 1575.1 506.66
H3 (DV) 1200.0 1276.0 1735.8 1438.2
MASA_STR(OBJ) 20.375 19.903 20.694 42.872
SET 5 SET 6 SET 7 SET 8
(FEASIBLE) (FEASIBLE) (FEASIBLE) (FEASIBLE)
H1 (DV) 1140.6 724.89 1946.8 1793.1
H2 (DV) 2085.5 1380.4 743.59 1521.8
H3 (DV) 1664.3 1559.5 2044.1 720.49
MASA_STR(OBJ) 29.674 32.553 41.364 17.074
SET 9 SET 10 SET 11 SET 12
(FEASIBLE) (FEASIBLE) (FEASIBLE) (FEASIBLE)
H1 (DV) 1696.4 2305.2 1234.7 2203.9
H2 (DV) 1530.4 2243.5 709.83 739.95
H3 (DV) 1014.9 892.09 557.11 560.66
MASA_STR(OBJ) 17.461 17.358 21.790 25.816
SET 13 SET 14 SET 15 SET 16
(FEASIBLE) (FEASIBLE) (FEASIBLE) (FEASIBLE)
H1 (DV) 1968.1 1975.4 1989.6 1986.0
H2 (DV) 1724.8 1733.6 1730.9 1970.4
H3 (DV) 995.08 987.79 967.71 727.06
MASA_STR(OBJ) 17.120 17.102 17.079 17.199
*SET 17* SET 18 SET 19
(FEASIBLE) (FEASIBLE) (FEASIBLE)
7

H1 (DV) 1921.9 1961.6 1963.6
H2 (DV) 1740.9 1810.4 1808.7
H3 (DV) 839.13 875.44 877.56
MASA_STR(OBJ) 16.945 16.966 16.965
Dacă se trasează graficele variaŃiei parametrilor funcŃie de seturile obŃinute în algoritmul de
optimizare (Fig. 9.7 - Fig. 9.9) se observă că metoda de optimizare aleasă converge neuniform către
soluŃia obŃinută pe cale analitică. Din cauza toleranŃei funcŃiei obiectiv 0.001, algoritmul se opreşte
înainte de a atinge valorile teoretice, mai mult condiŃia de convergenŃă este îndeplinită în ultimile
două seturi care nu fac parte din cea mai bună aproximare.
Fig. 9.7: VariaŃia funcŃiei obiectiv în funcŃie de numărul iteraŃiei pentru metoda “Subproblem
Approximation”
Fig. 9.8: VariaŃia variabilelor de proiectare în funcŃie de numărul iteraŃiei pentru metoda “Subproblem
Approximation”
8

Fig. 9.9: VariaŃia eforturilor în bare în funcŃie de numărul iteraŃiei pentru metoda “Subproblem
Approximation”
3. Optimizare cu MEF fără abordare analitică
Dacă se face abstracŃie de abordarea analitică, se poate crea fişierul de comenzi
COM_SS1.txt (prezentat mai jos) care se salvează în directorul curent (de lucru) şi prin rularea
procedurilor de optimizare în aceleaşi condiŃii ca la paragraful precedent se obŃin exact aceleaşi
rezultate deoarece problema de optimizat este aceeaşi. Avantajul acestei abordări constă în evitarea
calculelor analitice. Totuşi, s-a Ńinut seama că sistemul este static determinat şi eforturile nu depind
de aria secŃiunii barelor.
! GRINDA CU ZABRELE IN CONSOLA STATIC DETERMINATA
! OPTIMIZARE PENTRU GREUTATE MINIMA(H1,H2,H3)
! ABORDARE CU METODA ELEMENTELOR FINITE - Stefan SOROHAN
!*
*SET,F,10000
*SET,L,1000
*SET,S_A,150 ! TENSIUNEA ADMISIBILA
*SET,E,2E5 ! MODULUL DE ELASTICITATE
*SET,RO,7.85E-6 ! DENSITATEA IN kg/mm^3
*SET,A0,100 ! ARIA INITIALA, CONSTANTA LA TOATE ELEMENTELE
!*
/PREP7
*SET,H1,1200
*SET,H2,1200
*SET,H3,1200
!*
ET,1,LINK1
R,1,A0
MP,EX,1,E
MP,DENS,1,RO
!*
! CREEAZA NODURILE
N,1,3*L,0
N,2,2*L,0
N,3,L,0
N,4,0,0
N,5,2*L,H3
N,6,L,H2
N,7,0,H1
!*
! CREEAZA ELEMENTELE CU ARIA INITIALA A0
REAL,1
E,1,2
E,1,5
E,2,5
E,2,3
9

E,3,5
E,5,6
E,3,6
E,3,4
E,4,6
E,6,7
E,4,7
EPLOT ! SE PLOTEAZA ELEMENTELE FINITE IN CONFIGURATIA CURENTA
FINISH
!*
! CONDITII LA LIMITA SI ANALIZA PENTRU DETERMINAREA EFORTURILOR IN BARE
/SOLU
D,4,ALL,0
D,7,UX,0
F,1,FY,-F
F,5,FY,-2*F
F,6,FY,-2*F
F,7,FY,-F
SOLVE ! REZOLVARE CU ARII CONSTANTE
FINISH
!*
!* ANALIZA REZULTATELOR PENTRU CORECTIA ARIILOR
/POST1
ETABLE,MFORX_E,SMISC,1 ! FORTELE AXIALE IN ELEMENTE
*GET,NE,ELEM,,COUNT ! NUMARUL TOTAL DE ELEMENTE FINITE (SELECTATE)
*DIM,A_E,ARRAY,NE,1,1, , , ! DIMENSIONEAZA UN VECTOR PENTRU ARIILE TUTUROR
ELEMENTELOR
*DIM,N_E,ARRAY,NE,1,1, , , ! DIMENSIONEAZA UN VECTOR PENTRU FORTELE AXIALE
DIN ELEMENTE
*VGET,N_E(1),ELEM,1,ETAB,MFORX_E, ,2 ! ATRIBUIE VALORILE EFORTURILOR DIN
ETABLE IN VECTORUL N_E
!*
!* CALCULEAZA VECTORUL ARIILOR OPTIME (CARE ASIGURA TENSIUNEA S_A)
*DO,I,1,NE,1
A_E(I)=ABS(N_E(I))/S_A
*IF,A_E(I),LT,1E-6,THEN ! PENTRU ELEMENTELE CARE POT LIPSI SE CONSIDERA O
ARIE MICA
A_E(I)=1E-6
*ENDIF
*ENDDO
FINISH
!*
! ATRIBUIRE ARIA NECESARA PENTRU FIECARE ELEMENT-SE ASIGURA TENSIUNEA
ADMISIBILA
/PREP7
*DO,I,1,NE,1
R,I,A_E(I)
*ENDDO
!*
! MODIFICAREA PROPRIETATILOR SECTIUNILOR IN MODEL
*DO,I,1,NE,1
EMODIF,I,REAL,I,
*ENDDO
FINISH
!*
/SOLU
SOLVE ! SE REZOLVA PROBLEMA IN SITUATIA PENTRU CARE TENSIUNILE SUNT
EGALE CU S_A
FINISH
!*
!* EXTRAGEREA VOLUMULUI TOTAL AL ELEMENTELOR SI A TENSIUNILOR DIN BARE
/POST1
ETABLE,SAXL_E,LS,1 ! TENSIUNEA AXIALA IN ELEMENTE
ETABLE,VOL_E,VOLU, ! VOLUMELE ELEMENTELOR CU ARIA OPTIMA
DETERMINATA
!* SE DETERMINA VOLUMUL TOTAL
SSUM
*GET,VOL_TOT,SSUM,,ITEM,VOL_E
MASA_STR=VOL_TOT*RO ! IN KG
FINISH
10

4. Dimensionarea inelară secŃiunilor
Ariile obŃinute din analiza precedentă, pot fi folosite la dimensionarea secŃiunilor de formă
inelară pentru a putea prelua sarcini de compresiune fără ca barele să flambeze. Pentru aceasta se
Ńine seama de relaŃiile care definesc aria şi momentul de inerŃie al secŃiunii inelare:
2 2
D ( 1 k )
A π −
4 4
π D ( 1−
k )
= ; I = ,
4
64
d
în care k = este raportul diametrelor de interior şi exterior.
D
O bară articulată la capete, de lungime l , solicitată la compresiune cu o forŃă N şi care
trebuie să asigure un coeficient de siguranŃă la flambaj c în domeniul elastic, trebuie să prezinte
un moment de inerŃie minim care se determină cu relaŃia lui Euler
2
c
f
Nl Imin =
2 .
π E
Folosind aria optimizată a secŃiunilor şi expresia momentului de inerŃie minim necesar se
poate obŃine diametrul exterior şi interior al Ńevilor
8I
2A
8I
2A
D = + ; d = − .
A π
A π
Pentru o bară solicitată la întindere, de regulă se alege k = 0,8… 0,9 şi diametrele se obŃin
numai din valoarea ariei necesare, adică
4A
D = ; d = kD .
2
π 1−
k
( )
Fişierul de comenzi COM_SS2.txt care poate fi folosit la determinarea diametrului exterior
D − d
şi a grosimii de perete t = şi care salvează rezultatele în două fişiere text este
2
! GRINDA CU ZABRELE IN CONSOLA STATIC DETERMINATA
! CALCUL PENTRU O CONFIGURATIE PARTICULARA CU DIMENSIONAREA SECTIUNILOR
! ABORDARE CU METODA ELEMENTELOR FINITE - Stefan SOROHAN
!*
*SET,F,10000
*SET,L,1000
*SET,S_A,150 ! TENSIUNEA ADMISIBILA
*SET,E,2E5 ! MODULUL DE ELASTICITATE
*SET,RO,7.85E-6 ! DENSITATEA IN kg/mm^3
*SET,A0,100 ! ARIA INITIALA, CONSTANTA LA TOATE ELEMENTELE
!*
/PREP7
*SET,H1,1975 ! VALORI OPTIMIZATE
*SET,H2,1765
*SET,H3,792
!*
ET,1,LINK1
R,1,A0
MP,EX,1,E
MP,DENS,1,RO
!*
! CREEAZA NODURILE
N,1,3*L,0
N,2,2*L,0
N,3,L,0
N,4,0,0
N,5,2*L,H3
N,6,L,H2
N,7,0,H1
! CREEAZA ELEMENTELE CU ARIA INITIALA A0
REAL,1
E,1,2
E,1,5
11
f

E,2,5
E,2,3
E,3,5
E,5,6
E,3,6
E,3,4
E,4,6
E,6,7
E,4,7
EPLOT ! SE PLOTEAZA ELEMENTELE FINITE IN CONFIGURATIA CURENTA
FINISH
!*
! CONDITII LA LIMITA SI ANALIZA PENTRU DETERMINAREA EFORTURILOR IN BARE
/SOLU
D,4,ALL,0
D,7,UX,0
F,1,FY,-F
F,5,FY,-2*F
F,6,FY,-2*F
F,7,FY,-F
SOLVE ! REZOLVARE CU ARII CONSTANTE
FINISH
!*
!* ANALIZA REZULTATELOR PENTRU CORECTIA ARIILOR
/POST1
ETABLE,MFORX_E,SMISC,1 ! FORTELE AXIALE IN ELEMENTE
*GET,NE,ELEM,,COUNT ! NUMARUL TOTAL DE ELEMENTE FINITE (SELECTATE)
*DIM,A_E,ARRAY,NE,1,1, , , ! DIMENSIONEAZA UN VECTOR PENTRU ARIILE TUTUROR ELEMENTELOR
*DIM,N_E,ARRAY,NE,1,1, , , ! DIMENSIONEAZA UN VECTOR PENTRU FORTELE AXIALE DIN ELEMENTE
*VGET,N_E(1),ELEM,1,ETAB,MFORX_E, ,2 ! ATRIBUIE VALORILE EFORTURILOR DIN ETABLE IN
VECTORUL N_E
!*
!* CALCULEAZA VECTORUL ARIILOR OPTIME (CARE ASIGURA TENSIUNEA S_A)
*VSCFUN,N_MED,RMS,N_E ! SE DETERMINA VALOAREA MEDIE=RADICAL DIN SUMA PATRATELOR
*DO,I,1,NE,1
A_E(I)=ABS(N_E(I))/S_A
*IF,A_E(I),LT,1E-6,THEN ! PENTRU ELEMENTELE CARE POT LIPSI SE CONSIDERA O ARIE MEDIE
A_E(I)=N_MED/S_A
*ENDIF
*ENDDO
FINISH
!*
! ATRIBUIRE ARIA NECESARA PENTRU FIECARE ELEMENT-SE ASIGURA TENSIUNA ADMISIBILA
/PREP7
*DO,I,1,NE,1
R,I,A_E(I)
*ENDDO
!*
! MODIFICAREA PROPRIETATILOR SECTIUNILOR IN MODEL
*DO,I,1,NE,1
EMODIF,I,REAL,I,
*ENDDO
FINISH
!*
/SOLU
SOLVE ! SE REZOLVA PROBLEMA IN SITUATIA PENTRU CARE TENSIUNILE SUNT EGALE CU S_A
FINISH
!*
!* EXTRAGEREA VOLUMULUI TOTAL AL ELEMENTELOR SI A TENSIUNILOR DIN BARE
/POST1
ETABLE,SAXL_E,LS,1 ! TENSIUNEA AXIALA IN ELEMENTE
ETABLE,VOL_E,VOLU, ! VOLUMELE ELEMENTELOR CU ARIA OPTIMA DETERMINATA
!* SE DETERMINA VOLUMUL TOTAL
SSUM
*GET,VOL_TOT,SSUM,,ITEM,VOL_E
MASA_STR=VOL_TOT*RO ! IN KG
!*
!***********************************************************************************
!* SECVENTA DE DIMENSIONARE A ARIILOR IN SECTIUNI INELARE CU INCLUDEREA FLAMBAJULUI
!***********************************************************************************
*DIM,D_EXT,ARRAY,NE,1,1, , , ! DIMENSIONEAZA UN VECTOR PENTRU DIAMETRUL EXTERIOR
ELEMENTELOR
12

*DIM,D_INT,ARRAY,NE,1,1, , , ! DIMENSIONEAZA UN VECTOR PENTRU DIAMETRUL INTERIOR
ELEMENTELOR
*DIM,T_E,ARRAY,NE,1,1, , , ! DIMENSIONEAZA UN VECTOR PENTRU GROSIMEA CARNII TEVILOR
!*
PI=ACOS(-1) ! NUMARUL PI=3.1415...
C_F=2 ! COEFICIENTUL DE SIGURANTA LA FLAMBAJ
K_S=0.8 ! COEFICIENT DE FORMA SECTIUNE PREFERAT k=d/D
!*
*DO,I,1,NE,1
! PENTRU ELEMENTELE COMPRIMATE SE FOLOSESTE RELATIA EULER FARA VERIFICARE COEF DE
ZVELTETE
*IF,N_E(I),LT,0,THEN ! PENTRU ELEMENTELE COMPRIMATE
*GET,LBI,ELEM,I,LENG ! SE EXTRAGE LUNGIMEA ELEMENTULUI I
I_MIN=-C_F*LBI**2*N_E(I)/E/PI**2 ! MOMENTUL DE INERTIE MINIM NECESAR DUPA EULER
! SE POATE DETERMINA UN DIAMETRU EXTERIOR SI UNUL INTERIOR OPTIM DAR NU SE ASIGURA
K_S=0.8-0.9
! POT REZULTA GROSIMI DE CARNE PREA MICI
*IF,A_E(I),LT,2*SQRT(PI*I_MIN),THEN
D_EXT(I)=SQRT(8*I_MIN/A_E(I)+2*A_E(I)/PI) ! DIAMETRUL EXTERIOR
D_INT(I)=SQRT(8*I_MIN/A_E(I)-2*A_E(I)/PI) ! DIAMETRUL INTERIOR
*ELSE ! SE DETERMINA UN DIAMETRU EXTERIOR SI UNUL INTERIOR d=K_S*D
D_EXT(I)=SQRT(4*A_E(I)/PI/(1-K_S**2)) ! DIMENSIONARE DIN ARIA OPTIMIZATA
D_INT(I)=K_S*D_EXT(I)
*ENDIF
*ELSE ! PENTRU ELEMENTELE SOLICITATE LA INTINDERE
D_EXT(I)=SQRT(4*A_E(I)/PI/(1-K_S**2))
D_INT(I)=K_S*D_EXT(I)
*ENDIF
T_E(I)=(D_EXT(I)-D_INT(I))/2 ! GROSIME CARNE TEAVA
*ENDDO
!*
! SE SALVEAZA DIAMETRELE EXTERIOARE OBTINUTE SI GROSIMEA CARNII TEVILOR ADOPTATE
!*
*CFOPEN,'D_EXT','TXT',' '
*VWRITE,D_EXT(1),
(F12.6)
*CFCLOSE
*CFOPEN,'T_E','TXT',' '
*VWRITE,T_E(1),
(F12.6)
*CFCLOSE
FINISH
Folosind acest fişier se obŃin valorile de mai jos. Se observă că unele grosimi ale pereŃilor
sunt mici, relativ la diametrul exterior, din cauza necesarului de moment de inerŃie pentru asigurarea
coeficientului de siguranŃă la flambaj. Bara 3, nesolicitată a fost dimensionată cu o forŃă medie. Ea
nu poate lipsi deoarece structura se transformă în mecanism. În continuare se consideră că flambajul
barelor comprimate este de tip elastic deşi e posibil să nu fie adevărat.
Bara Ariile secŃiunilor
[mm 2 ]
Tensiunile în bare
[MPa]
Diametrul exterior
[mm]
Grosimea peretelui
[mm]
1 84.1733 -150 35.629226 0.768597
2 107.3800 150 19.487678 1.948768
3 0 0 24.413954 2.441395
4 84.1733 -150 35.629226 0.768597
5 85.3533 -150 45.087182 0.610867
6 210.8000 150 27.305001 2.730500
7 52.9933 150 13.690353 1.369035
8 151.0867 -150 36.222072 1.380301
9 309.7933 -150 72.116105 1.394330
10 310.4267 150 33.134575 3.313458
11 130.4667 -150 69.466880 0.603045
13

5. Modelul optimizat din Ńevi articulate
Folosind dimensionarea de mai sus, se poate genera un model cu elemente finite de tip
grindă (Ńeavă) cu articulaŃii cilindrice la îmbinări care să folosească la determinarea coeficienŃilor de
siguranŃă efectivi la flambaj şi a frecvenŃelor proprii de vibraŃie. Fişierul de comenzi COM_SS3.txt
care realizează acest model şi analizele cerute este:
! GRINDA CU ZABRELE IN CONSOLA STATIC DETERMINATA
! MODELARE CU TEVI ARTICULATE 2D PENTRU ANALIZA STATICA, STABILITATE SI MODURI PROPRII
! ABORDARE CU METODA ELEMENTELOR FINITE - Stefan SOROHAN
!*
*SET,NE,11 ! NUMARUL DE TEVI
*SET,A_G,10 ! ACCELERATIA GRAVITATIONALA m/s^2
*SET,F,10000
*SET,L,1000
*SET,E,2E5 ! MODULUL DE ELASTICITATE
*SET,NIU,0.3 ! COEFICIENTUL DE CONTRACTIE TRANSVERSALA
*SET,RO,7.85E-6 ! DENSITATEA IN kg/mm^3
! SE CITESC DIAMETRELE SI GROSIMILE DE PERETE ALE TEVILOR DIN FISIERE
*DIM,D_EXT,ARRAY,11,1,1, , , !* VECTORUL DIAMETRELOR EXTERIOARE
*DIM,T_E,ARRAY,11,1,1, , , !* VECTORUL GROSIMILOR
!*
*VREAD,D_EXT(1),D_EXT,TXT,
(F12.6)
*VREAD,T_E(1),T_E,TXT,
(F12.6)
!*
/PREP7
*SET,H1,1975 ! VALORI OPTIMIZATE
*SET,H2,1765
*SET,H3,792
!*
ET,1,PIPE16 ! ELEMENT FINIT DE TIP TEAVA
! SE CREEAZA PROPRIETATILE TEVILOR
*DO,I,1,NE,1
R,I,D_EXT(I),T_E(I),
*ENDDO
!* DATE DESPRE MATERIALE
MP,EX,1,E
MP,NUXY,1,NIU
MP,DENS,1,1E-3*RO ! DENSITATEA IN t/mm^3
!*
! CREEAZA PUNCTELE DE IMBINARE PRIN ARTICULATIE (KEYPOINTS)
K,1,3*L,0
K,2,2*L,0
K,3,L,0
K,4,0,0
K,5,2*L,H3
K,6,L,H2
K,7,0,H1
K,8,3*L,0
K,9,2*L,0
K,12,L,0
K,18,0,0
K,10,2*L,H3
K,17,L,H2
K,22,0,H1
K,11,2*L,0
K,13,L,0
K,21,0,0
K,14,2*L,H3
K,19,L,H2
K,16,L,0
K,15,2*L,H3
K,20,L,H2
! CREEAZA LINIILE
L,1,2
L,8,5
14

L,9,10
L,11,3
L,13,14
L,15,6
L,17,16
L,12,4
L,18,19
L,20,7
L,21,22
! ATRIBUTE PENTRU DISCRETIZARE
*DO,I,1,NE,1
LSEL,S,,,I
LATT,1,I,1, , , ,
*ENDDO
LSEL,ALL
ESIZE,L/10 ! DIMENSIUNEA MEDIE A ELEMENTELOR FINITE
LMESH,ALL ! DISCRETIZAREA
! LCLEAR,3 ! TEAVA 3 NU SE INCLUDE PT CA E FOARTE SUBTIRE DAR SUNT PROBLEME LA FLAMBAJ
!*
!* CUPLAREA GRADELOR DE LIBERTATE UX SI UY IN ARTICULATII
!*
CPINTF,UX,0.0001,
CPINTF,UY,0.0001,
FINISH
!*
! CONDITII LA LIMITA SI ANALIZA PENTRU DETERMINAREA EFORTURILOR IN BARE
!*
/SOLU
DK,4,UX,0
DK,4,UY,0
DK,7,UX,0
! CONDITII LA LIMITA PENTRU MODELARE 2D
DL,ALL,,UZ,0
DL,ALL,,ROTX,0
DL,ALL,,ROTY,0
! APLICAREA FORTELOR IN KEYPOINTS
FK,1,FY,-F
FK,5,FY,-2*F
FK,6,FY,-2*F
FK,7,FY,-F
PSTRES,1 ! CALCULEAZA EFECTUL TENSIUNILOR INITIALE PENTRU CALCUL DE STABILITATE
LPLOT ! SE PLOTEAZA LINIILE IN CONFIGURATIA CURENTA
SOLVE ! REZOLVARE STATICA
FINISH
!* EXTRAGEREA VOLUMULUI TOTAL AL ELEMENTELOR SI A TENSIUNILOR DIN BARE
/POST1
ETABLE,SAXL_E,LS,1 ! TENSIUNEA AXIALA IN ELEMENTE
ETABLE,VOL_E,VOLU, ! VOLUMELE ELEMENTELOR CU ARIA OPTIMA DETERMINATA
!* SE DETERMINA VOLUMUL TOTAL
SSUM
*GET,VOL_TOT,SSUM,,ITEM,VOL_E
MASA_STR=VOL_TOT*RO ! IN KG
!*
ETABLE,SEQV_MXE,NMISC,89 ! TENSIUNEA ECHIVALENTA MAXIMA IN ELEMENTE
ESORT,ETAB,SEQV_MXE,1 ! SORTEAZA TENSIUNILE DEFINITE IN ORDINE CRESCATOARE
*GET,SEQV_MAX,SORT,0,MAX ! EXTRAGE VALOAREA MAXIMA DIN ULTIMUL SORT
!*
NOD_DR=NODE(3*L,0,0) ! EXTRAGE NUMARUL NODULUI DIN CAPATUL DREAPTA
DEPL_VERT=UY(NOD_DR) ! SE EXTRAGE DEPLASAREA VERTICALA A NODULUI
FINISH
!*
!* ANALIZA DE STABILITATE
!*
/SOLU
!*
ANTYPE,1 ! EIGENBUCKLING
BUCOPT,LANB,10,0,0 ! SE CALCULEAZA PRIMELE 10 MODURI DE PIERDERE STABILITATE
!*
SOLVE
FINISH
/POST1
SET,FIRST ! SE CITESTE IN MEMORIE MODUL 1
PLNSOL,U,SUM ! SE PLOTEAZA MODUL 1
15

WAIT,2 ! PAUZA 2 SECUNDE
*GET,COEF_SIG_FL,MODE,1,FREQ ! EXTRAGE COEFICIENTUL DE SIGURANTA LA FLAMBAJ
FINISH
!*
!* COMPLETAREA CU ELEMENTELE DE MASA ATASATE LA FORTE PENTRU ANALIZA MODALA
!*
/PREP7
!*
ET,2,MASS21,0,0,4 ! ELEMENT FINIT DE MASA CONCENTRATA 2D
!*
!* ATRIBUIRE VALORI PENTRU MASELE ATASATE
!*
R,12,F/1000/A_G, ! MASA FORTEI F (IN tone)
R,13,2*F/1000/A_G, ! MASA FORTEI 2F (IN tone)
!*
!* DEFINIRE ELEMENTE DE MASA IN POZITIA FORTELOR APLICATE
TYPE,2
REAL,12
NOD_F=NODE(3*L,0,0) ! EXTRAGE NUMARUL NODULUI IN CARE EXISTA MASA
E,NOD_F ! DEFINESTE ELEMENTUL DE MASA IN NOD_F
NOD_F=NODE(0,H1,0)
E,NOD_F
REAL,13
NOD_F=NODE(L,H2,0)
E,NOD_F
NOD_F=NODE(2*L,H3,0)
E,NOD_F
FINISH
!*
!* ANALIZA MODALA CU INCLUDEREA EFECTULUI PRESTRESS
!*
/SOLU
ANTYPE,0 ! STATIC
PSTRES,1
SOLVE ! SE EFECTUEAZA MAI INTAI O ANALIZA STATICA PENTRU A INCLUDE EFECTUL PRESTRESS
FINISH
/SOLU
ANTYPE,2 ! MODAL
MODOPT,LANB,10 ! SE CALCULEAZA PRIMELE 10 MODURI PROPRII
MXPAND,10
PSTRES,1 ! SE TINE SEAMA DE TENSIUNILE INITIALE CALCULATE ANTERIOR
MODOPT,LANB,10,0,10000, ,OFF
SOLVE
FINISH
/POST1
SET,FIRST
PLNSOL,U,SUM
*GET,FRECV_1,MODE,1,FREQ ! EXTRAGE FRECVENTA FUNDAMENTALA
FINISH
Folosind acest model se obŃin rezultatele din Fig. 9.10 - Fig. 9.12 şi următoarele valori
extrase de program:
COEF_SIG_FL=1.984515119921
DEPL_VERT=-8.498288674234
FRECV_1= 6.075677123599
MASA_STR=17.97435123139
SEQV_MAX=150.0001177232
Se observă că Ńevile sunt solicitate cu tensiunile admisibile, mai puŃin bara 3 care rezultă
nesolicitată. Din analiza modurilor de pierdere a stabilităŃii se constată că cele şase bare comprimate
prezintă acelaşi coeficient de siguranŃă la flambaj, foarte aproape de valoarea impusă egală cu 2.
Primele 6 moduri proprii de vibraŃie sunt globale, următoarele patru sunt moduri locale în care o
singură Ńeavă “vibrează”.
16

Fig. 9.10: Diagrama eforturilor axiale şi a tensiunilor normale pentru modelul cu Ńevi articulate la îmbinări
17

Fig. 9.11: Modurile de pierdere a stabilitaŃii şi coeficienŃii de siguranŃă pentru modelul optimizat cu Ńevi
articulate la îmbinări
18

Fig. 9.12: Modurile de vibraŃie şi frecvenŃele proprii pentru modelul optimizat cu Ńevi articulate la îmbinări
6. Model optim din Ńevi sudate
Pentru a obŃine modelul Ńevilor îmbinate prin sudură, se renunŃă la cuplajele definite anterior
precum şi la nodurile coincidente, practic în fişierul precedent nu se mai declară puncte separate
pentru definirea liniilor care definesc barele. Prin analiza acestui model, rezultatele se modifică dar
nu în proporŃie foarte mare. De exemplu mărimile globale salvate în modelul precedent devin:
COEF_SIG_FL= 2.877702397220
DEPL_VERT= -8.495455716953
FRECV_1= 6.079283852880
MASA_STR= 17.97435123139
SEQV_MAX= 189.7486121208
Modurile de pierdere a stabilităŃii şi modurile proprii de vibraŃie se prezintă în Fig. 9.13 şi
Fig. 9.14. Se observă că modurile de pierdere a stabilităŃii sunt globale şi prezintă coeficienŃi de
siguranŃă mai mari decât în cazul barelor articulate.
19

Fig. 9.13: Modurile de pierdere a stabilitaŃii şi coeficienŃii de siguranŃă pentru modelul optimizat cu Ńevi
sudate între ele
Modurile proprii de vibraŃie de tip global (primele şase) şi frecvenŃele acestora, practic
rămân nemodificate faŃă de situaŃia de îmbinare articulată.
20

Fig. 9.14: Modurile de vibraŃie şi frecvenŃele proprii pentru modelul optimizat cu Ńevi sudate între ele
Diagramele de eforturi N, T şi M şi distribuŃia tensiunilor maxime generate de aceste eforturi
se prezintă în Fig. 9.15. Se observă că practic eforturile axiale rămân aceleaşi ca în cazul modelului
de bare articulate în timp ce eforturile tăietoare şi de momente încovoietoare prezintă valori relativ
reduse. Totuşi tensiunea maximă creşte la circa 190 MPa (Fig. 9.16).
21

Fig. 9.15: DistribuŃia eforturilor N, T şi M precum şi a tensiunilor maxime generate de acestea, în modelul cu
Ńevi îmbinate prin sudură
7. Concluzii
Modelul dezvoltat pentru elementele constructive de tip Ńeavă sudată prezintă inconvenientul
că grosimea pereŃilor de Ńeavă solicitată la compresiune rezultă prea mică pentru diametrul exterior
d
al Ńevilor. OperaŃia de optimizare poate continua prin impunerea unui coeficient de formă k =
D
dorit şi pentru barele comprimate. De exemplu, dacă pentru barele comprimate se impune k =0,8,
greutatea totală a structurii creşte pentru configuraŃia optimizată cu elemente de tip LINK1.
Pentru dimensionarea precizată se poate folosi secvenŃa de comenzi de mai jos care
înlocuieşte secvenŃa finală din fişierul COM_SS2.txt.
!***********************************************************************************
!* SECVENTA DE DIMENSIONARE A ARIILOR IN SECTIUNI INELARE CU INCLUDEREA FLAMBAJULUI
!***********************************************************************************
*DIM,D_EXT,ARRAY,NE,1,1, , , ! DIMENSIONEAZA UN VECTOR PENTRU DIAMETRUL EXTERIOR
ELEMENTELOR
*DIM,D_INT,ARRAY,NE,1,1, , , ! DIMENSIONEAZA UN VECTOR PENTRU DIAMETRUL INTERIOR
ELEMENTELOR
*DIM,T_E,ARRAY,NE,1,1, , , ! DIMENSIONEAZA UN VECTOR PENTRU GROSIMEA CARNII TEVILOR
!*
PI=ACOS(-1) ! NUMARUL PI=3.1415...
C_F=2 ! COEFICIENTUL DE SIGURANTA LA FLAMBAJ
K_S=0.8 ! COEFICIENT DE FORMA SECTIUNE PREFERAT k=d/D
!*
*DO,I,1,NE,1
! PENTRU ELEMENTELE COMPRIMATE SE FOLOSESTE RELATIA EULER FARA VERIFICARE COEF DE
ZVELTETE
*IF,N_E(I),LT,0,THEN ! PENTRU ELEMENTELE COMPRIMATE
*GET,LBI,ELEM,I,LENG ! SE EXTRAGE LUNGIMEA ELEMENTULUI I
I_MIN=-C_F*LBI**2*N_E(I)/E/PI**2 ! MOMENTUL DE INERTIE MINIM NECESAR DUPA EULER
D_EXT1=(64*I_MIN/PI/(1-K_S**4))**0.25 ! DIMENSIONARE DIN FLAMBAJ
D_EXT2=SQRT(4*A_E(I)/PI/(1-K_S**2)) ! DIMENSIONARE DIN ARIA OPTIMIZATA
D_EXT(I)=D_EXT1>D_EXT2 ! SE ALEGE DIAMETRUL MAXIM - ATENTIE ARIA POATE
CRESTE!!!
D_INT(I)=K_S*D_EXT(I)
*MSG, UI,D_EXT2,D_EXT1,I ! ATENTIONARE CA ARIILE SE POT MODIFICA
D_OPTIM = %G, D_FLAMBAJ = %G, Elementul = %I
/WAIT,2
! PAUZA DE 2 SECUNDE PT A CITI MESAJUL
*ELSE ! PENTRU ELEMENTELE SOLICITATE LA INTINDERE
D_EXT(I)=SQRT(4*A_E(I)/PI/(1-K_S**2))
D_INT(I)=K_S*D_EXT(I)
*ENDIF
T_E(I)=(D_EXT(I)-D_INT(I))/2 ! GROSIME CARNE TEAVA
*ENDDO
!*
! SE SALVEAZA DIAMETRELE EXTERIOARE OBTINUTE SI GROSIMEA CARNII TEVILOR ADOPTATE
!*
*CFOPEN,'D_EXT','TXT',' '
*VWRITE,D_EXT(1),
(F12.6)
*CFCLOSE
*CFOPEN,'T_E','TXT',' '
*VWRITE,T_E(1),
(F12.6)
*CFCLOSE
FINISH
Pentru valorile optimizate anterior, adică H 1 = 1975 mm, H 2 = 1765 mm şi H 3 = 792 mm
rezultă
22

Bara Diametrul exterior
[mm]
Grosimea peretelui
[mm]
Tensiunile în bare
[MPa]
1 25.775952 2.577595 -67.213
2 19.487678 1.948768 150
3 24.413954 2.441395 0
4 25.775952 2.577595 -67.213
5 29.213911 2.921391 -53.057
6 27.305001 2.730500 150
7 13.690353 1.369035 150
8 29.834916 2.983492 -90.048
9 50.849229 5.084923 -63.562
10 33.134575 3.313458 150
11 40.418031 4.041803 -42.368
Model cu Ńevi articulate
COEF_SIG_FL= 1.990742098028
DEPL_VERT= -6.190172140347
FRECV_1= 7.227152837090
MASA_STR= 33.80058204398
SEQV_MAX= 150.0000386666
Model cu Ńevi sudate
COEF_SIG_FL= 2.899697195140
DEPL_VERT= -6.189097719562
FRECV_1 = 7.230239533128
MASA_STR= 33.80058204398
*SEQV_MAX= 159.5885479743
Pentru o serie de valori alese din considerente estetice: H 1 = 900 mm, H 2 = 600 mm şi H 3 =
300 mm şi dimensionare Ńevilor din condiŃia de stabilitate la compresiune şi arie minimă necesară
rezultă
Bara Diametrul exterior
[mm]
Grosimea peretelui
[mm]
Tensiunile în bare
[MPa]
1 36.841896 2.032056 -150
2 28.645353 2.864535 150
3 34.504181 3.450418 0
4 36.841896 2.032056 -150
5 38.379437 2.031769 -150
6 40.510647 4.051065 150
7 15.355296 1.535530 150
8 38.714291 4.085341 -150
9 42.644389 2.031137 -150
10 49.615207 4.961521 150
11 33.979511 2.714982 -150
Model cu Ńevi articulate
COEF_SIG_FL = 1.984561413005
DEPL_VERT = -16.34999867493
FRECV_1 = 4.456701061186
MASA_STR = 25.65106709433
SEQV_MAX = 150.0000291242
Model cu Ńevi sudate
COEF_SIG_FL= 2.979632550295
DEPL_VERT= -16.26738906026
FRECV_1 =4.475356030336
MASA_STR= 25.65106709433
SEQV_MAX= 198.6554910865
Pentru H 1 = 900 mm, H 2 = 600 mm şi H 3 = 300 mm şi dimensionarea tuturor Ńevilor
(inclusiv a celor supuse la compresiune) cu k = 0,8 rezultă
23

Bara Diametrul exterior
[mm]
Grosimea peretelui
[mm]
Tensiunile în bare
[MPa]
1 32.856076 3.285608 -109.21
2 28.645353 2.864535 150
3 34.504181 3.450418 0
4 32.856076 3.285608 -109.21
5 33.935217 3.393522 -106.88
6 40.510647 4.051065 150
7 15.355296 1.535530 150
8 39.647203 3.964720 -150.00
9 36.871667 3.687167 -101.13
10 49.615207 4.961521 150
11 32.623628 3.262363 -132.92
Model cu Ńevi articulate
COEF_SIG_FL= 1.986374460744
DEPL_VERT= -14.91342809264
FRECV_1 = 4.716403507681
MASA_STR= 29.10993051285
SEQV_MAX= 150.0000126176
Model cu Ńevi sudate
COEF_SIG_FL= 3.054431238409
DEPL_VERT= -14.84545007406
FRECV_1 = 4.732391737916
MASA_STR= 29.10993051285
SEQV_MAX= 180.2754238620
Având în vedere că masa structurii pentru analizele prezentate cu secŃiunile de formă inelară
este variabilă, problema de optimizare se poate reformula şi analiza se poate efectua pentru noile
resticŃii de proiectare ale diametrului de Ńeavă, grosimea peretelui, săgeata maximă, coeficient de
siguranŃă la flambaj, frecvenŃa proprie fundamentală, etc. Practic optimizarea se încheie atunci când
structura satisface criteriile impuse şi aceasta a fost testată şi validată în practică.
24