eldo_user

Optimization
Scaling Design Variables
The result of this scaling procedure is described in the output file .otm, in the section headed
Section 2 - Scaling Transformation For Variables. For more information, refer to “Section 2 -
Scaling Transformation For Variables” on page 644.
This scaling strategy is not always appropriate and there are cases that need an alternative
approach. Consider the following example:
* Circuit Statements
.PARAM LOGL={LOG10(150U)}
.PARAM LOGR={LOG10(10)}
.PARAM LOGC={LOG10(10U)}
V1 1 0 AC 1
L1 1 2 5U
L2 2 3 150U
C1 3 0 33U
LA 2 2A {10^LOGL}
CA 2A 2B {10^LOGC}
RA 2B 3 {10^LOGR}
.AC DEC 500 1E2 1E5
* Optimization Commands
.OPTIMIZE
.PARAM LNOM={LOG10(150U)} LMIN={LOG10(150U)} LMAX={LOG10(1)}
.PARAMOPT LOGL=(LNOM,LMIN,LMAX)
.PARAM CNOM={LOG10(10U)} CMIN={LOG10(1P)} CMAX={LOG10(1)}
.PARAMOPT LOGC=(CNOM,CMIN,CMAX)
.PARAM RNOM={LOG10(10)} RMIN={LOG10(1E-3)} RMAX={LOG10(1E+6)}
.PARAMOPT LOGR=(RNOM,RMIN,RMAX)
.OBJECTIVE AC LABEL=Q MAX(W(’VM(3)’))
+ GOAL=MINIMIZE
This example represents a user-defined transformation based on the logarithmic function:
The exponent becomes the parameter to optimize. Consider the third .PARAMOPT command,
the original formulation would have been the following statements:
.PARAM RNOM=10 RMIN=1E-3 RMAX=1E+6
.PARAMOPT R=(RNOM, RMIN, RMAX)
The affine scaling transformation is not appropriate since the upper bound RMAX=1E+6 will
dominate inside the expression of the matrix D:
Eldo® User's Manual, 15.3 601