eldo_user

Monte Carlo Analysis
Further Examples
Further Examples
This section provides a selection of further examples:
• Device sizes can be subject to a probabilistic distribution, simulating process variation,
through the use of .PARAM statements. In this example, the NMOS transistor’s width
follows a Gaussian distribution, centered around 20e-6 with σ = 0.2×20e-6 = 4e-6 as
defined by the parameter nwidth. This parameter will also be subject to DEV variation.
A .EXTRACT measures the propagation time through the inverter. The .chi file contains
statistical information about the outcome of the .EXTRACT:
.MODEL N NMOS LEVEL=1 VTO=1.2 KP=2.5e-5 GAMMA=1.5
.MODEL P PMOS LEVEL=1 VTO=-1.5 KP=1.2e-5 GAMMA=1.2
.PARAM NWIDTH=GAUSS(20U,0.2,1)
M1 OUT IN VSS VSS N W=NWIDTH L=15U
M2 OUT IN VDD VDD p W=30U L=15U
COUT OUT 0 0.1P
VDD VDD 0 5
VSS VSS 0 0
VIN IN 0 PWL (0 0 50N 0 51N 5)
.MC 1000 ALL
.TRAN 1N 100N
.PROBE TRAN V(OUT)
.EXTRACT TRAN LABEL=TPD TPDUD(V(IN), V(OUT))
.END
The .PARAM usage may be applied to model parameters as well. The VTO of the
NMOS transistor can be replaced with a Gaussian random parameter. In this case, the
standard deviation σ is 0.24. This technique may be more useful if the parameter needs
to be a mathematical function of several variables.
.PARAM NVTO=GAUSS(1.2,0.2,1)
.MODEL N NMOS LEVEL=1 VTO=NVTO KP=2.5E-5 GAMMA=1.5
.MODEL P PMOS LEVEL=1 VTO=-1.5 KP=1.2E-5 GAMMA=1.2
M1 OUT IN VSS VSS N W=20U L=15U
M2 OUT IN VDD VDD P W=30U L=15U
COUT OUT 0 0.1P
VDD VDD 0 5
VSS VSS 0 0
VIN IN 0 PWL (0 0 50N 0 51N 5)
.MC 1000 ALL
.TRAN 1n 100n
.PROBE TRAN V(OUT)
.EXTRACT TRAN LABEL=TPD TPDUD(V(IN), V(OUT))
.END
534
Eldo® User's Manual, 15.3