eldo_user

Monte Carlo Analysis
Specifying Statistical Variations
.SUBCKT CAPA PLUS MINUS B
+ PARAM: CAREA=1.0 CPERI=2.0 C=-1 W=-1 MISMATCH=1 TOMETER=1E-6
.PARAM TOX_TYP = 1.9E-08
+ COX_TYP = ‘3.9 * 8.85418E-12 / TOX_TYP’
.PARAM D=’CPERI**2-4*CAREA’
.PARAM WDRAWN =
+‘VALIF((C>0)&&(W>0),W,
+ VALIF(D>0,SQRT(D)+CPERI,CPERI)/2)*TOMETER’
.PARAM LDRAWN =
+‘VALIF((C>0)&&(W>0),C/(COX_TYP*WDRAWN),
+ VALIF(D>0,CAREA/WDRAWN,WDRAWN))*TOMETER’
.PARAM A_MM_TOX=0.4543U B_MM_TOX=0.1435
+ DEV_MM_TOX = ’A_MM_TOX/SQRT(WDRAWN*LDRAWN)+B_MM_TOX’
.PARAM TOX = TOX_TYP DEV/GAUSS={DEV_MM_TOX}%
.PARAM COX = ‘3.9 * 8.85418E-12 / TOX’
.PARAM DL = 0.0 LOT/GAUSS={2.0E-09}
.PARAM DW = 0.0 LOT/GAUSS={5.0E-09}
.PARAM LEFF = ‘LDRAWN - DL’
.PARAM WEFF = ‘WDRAWN - DW’
.PARAM AEFF = ‘WEFF*LEFF’
*
CC PLUS MINUS VALUE=’COX * AEFF’
*
.ENDS CAPA
The subcircuit parameters also define intermediate values including the drawn length
LDRAWN and width WDRAWN of the device. These quantities are computed depending on
the values of capacitance C and width W, which are the input parameters of the subcircuit.
When the default value, -1, is used for these parameters the geometry is computed from
CAREA and CPERI. It may be more useful for a designer to specify the capacitance and width,
then calculate the drawn length at the layout stage.
The typical (or nominal) value of the COX parameter is used in the definition of the drawn
length:
You may use this value at layout time to determine the capacitor length that gives the desired
capacitance for a given width. Once a Monte Carlo analysis is started, the parameter COX will
be subject to statistical variations. This is why the typical value of the COX parameter is used,
because if the parameter COX were to be used in the previous expression instead of the nominal
value COX_TYP, different values for capacitor length would be calculated.
Eldo® User's Manual, 15.3 425