MetaFun - Pragma ADE

82
It is surprisingly difficult to find nice examples that demonstrate the difference between .. and
..., as it is often ‘impossible' to honour the request for less inflection. We will demonstrate this
with a few graphics.
In the four figures on the next pages, you will see that ... is not really suited for taming wild
curves. If you really want to make sure that a curve stays within certain bounds, you have to
specify it as such using control or intermediate points. In the figures that follow, the gray curves
draw the random path using .. on top of yellow curves that use the ... connection. As you can
see, in only a few occasions do the yellow ‘inflection' free curves show up.
For those who asked for the code that produces these pictures, we now include it here. We use a
macro sample which we define as a usable graphic (nearly all examples in this manual are coded
in the document source).
\startuseMPgraphic{sample}
def sample (expr rx, ry) =
path p, q ; numeric n, m, r, a, b ;
color c ; c := \MPcolor{lightgray} ;
a := 3mm ; b := 2mm ; r := 2cm ; n := 7 ; m := 5 ;
q := unitsquare scaled r xyscaled (n,m) shifted (.5r,.5r) ;
draw q withpen pencircle scaled (b/4) withcolor .625yellow;
for i=1 upto n : for j=1 upto m :
p := (fullcircle scaled r randomized (r/rx,r/ry))
shifted ((i,j) scaled r) ;
pickup pencircle scaled a ;
draw for k=0 upto length(p) :
point k of p .. endfor cycle withcolor c ;
draw for k=0 upto length(p) :
point k of p ... endfor cycle withcolor c ;
pickup pencircle scaled b ;
draw for k=0 upto length(p) :
point k of p .. endfor cycle withcolor .625yellow ;
draw for k=0 upto length(p) :
point k of p ... endfor cycle withcolor .625white ;
for k=0 upto length(p) :
draw point k of p withcolor .625red ;
endfor ;
endfor ; endfor ;
setbounds currentpicture to q ;
enddef ;
\stopuseMPgraphic
As you see, not so much code is needed. The graphics themselves were produced with a couple
of commands like:
\placefigure
{Circles with minimized inflection and 25\% randomized points.}
{\startMPcode
\includeMPgraphic{sample} ; sample(4,4) ;
\stopMPcode}
A few more details Inflection, tension and curl