MetaFun - Pragma ADE

Because in most cases we want the length to be consistent between figures and because passing
two paths is more convenient than passing three points, the final definition looks slightly different.
numeric anglelength ; anglelength := 20pt ;
vardef anglebetween (expr a, b, str) = % path path string
save endofa, endofb, common, curve, where ;
pair endofa, endofb, common ; path curve ; numeric where ;
endofa := point length(a) of a ;
endofb := point length(b) of b ;
if round point 0 of a = round point 0 of b :
common := point 0 of a ;
else :
common := a intersectionpoint b ;
fi ;
where := turningnumber (common--endofa--endofb--cycle) ;
curve := (unitvector (endofa-common){(endofa-common) rotated (where*90)} ..
unitvector (endofb-common)) scaled anglelength shifted common ;
draw thefreelabel(str,point .5 of curve,common) withcolor black ;
curve
enddef ;
This macro has a few more if's than its predecessor. First we test if the label is a string, and if so,
we calculate the picture ourselves, otherwise we leave this to the user.
path a, b, c, d, e, f ;
a := origin--( 2cm, 1cm) ; b := origin--( 1cm, 2cm) ;
c := origin--(-2cm, 2cm) ; d := origin--(-2cm,-1cm) ;
e := origin--(-1cm,-2cm) ; f := origin--( 1cm,-2cm) ;
for i=a, b, c, d, e, f : drawarrow i ; endfor ;
anglelength := 1.0cm ; drawoptions(withcolor .625red) ;
drawarrow anglebetween(a,b,btex $\alpha $ etex) ;
drawarrow anglebetween(c,d,btex $\gamma $ etex) ;
drawarrow anglebetween(e,f,btex $\epsilon$ etex) ;
anglelength := 1.5cm ; drawoptions(withcolor .625yellow) ;
drawdblarrow anglebetween(b,c,btex $\beta $ etex) ;
drawarrow reverse anglebetween(d,e,btex $\delta $ etex) ;
drawarrow anglebetween(a,f,btex $\zeta $ etex) ;
Because anglebetween returns a path, you can apply transformations to it, like reversing. Close
reading of the previous code learns that the macro handles both directions.
Marking angles A few applications
283