OpenOffice.org BASIC Guide - OpenOffice.org wiki

More Than Just Text
AnchorType (Enum)
determines the anchor type of a TextContent object (default values in accordance with
com.sun.star.text.TextContentAnchorType enumeration).
AnchorTypes (sequence of Enum)
enumeration of all AnchorTypes which support a special TextContent object.
TextWrap (Enum)
determines the text wrap type around a TextContent object (default values in accordance with
com.sun.star.text.WrapTextMode enumeration).
The TextContent objects also share some methods – in particular, those for creating, inserting and deleting
objects.
A new TextContent object is created using the createInstance method of the document object.
An object is inserted using the insertTextContent method of the text object.
TextContent objects are deleted using the removeTextContent method.
You will find a range of examples which use these methods in the following sections.
Tables
The following example creates a table with the help of the createInstance method described previously.
Dim Doc As Object
Dim Table As Object
Dim Cursor As Object
Doc = ThisComponent
Cursor = Doc.Text.createTextCursor()
Table = Doc.createInstance("com.sun.star.text.TextTable")
Table.initialize(5, 4)
Doc.Text.insertTextContent(Cursor, Table, False)
Once created, the table is set to the number of rows and columns requested using an initialize call and then
inserted in the text document using insertTextContent.
As can be seen in the example, the insertTextContent method expects not only the Content object to be
inserted, but two other parameters:
a Cursor object which determines the insert position
a Boolean variable which specifies whether the Content object is to replace the current selection of the
cursor (True value) or is to be inserted before the current selection in the text (False)
Note – VBA : When creating and inserting tables in a text document, objects similar to those available in VBA
are used in OpenOffice.org Basic: The document object and a TextCursor object in OpenOffice.org Basic, or
the Range object as the VBA counterpart. Whereas the Document.Tables.Add method takes on the task of
creating and setting the table in VBA, this is created in OpenOffice.org Basic in accordance with the previous
example using createInstance, initialized, and inserted in the document through insertTextContent.
The tables inserted in a text document can be determined using a simple loop. The method getTextTables()
of the text document object is used for this purpose:
Dim Doc As Object
Dim TextTables As Object
Dim Table As Object
Dim I As Integer
Doc = ThisComponent
TextTables = Doc.getTextTables()
For I = 0 to TextTables.count - 1
Table = TextTables(I)
' Editing table
Next I
82 OpenOffice.org 3.2 BASIC Guide · March 2010