SPSS® 12.0 Command Syntax Reference

DEFINE—!ENDDEFINE 445
• The macro call expands the macname macro. The argument is identified by its name, arg1,
and is assigned the value V1. V1 is substituted wherever !arg1 appears in the macro body.
The macro body in this example is the FREQUENCIES command.
Example
* A positional argument.
DEFINE macname (!POSITIONAL !TOKENS(1)
/!POSITIONAL !TOKENS(2))
frequencies variables = !1 !2.
!ENDDEFINE.
macname V1 V2 V3.
• The macro definition defines macname as the macro name with two positional arguments.
The first argument has one token and the second argument has two tokens. The tokens can
be assigned any values in the macro call.
• The macro call expands the macname macro. The arguments are identified by their positions.
V1 is substituted for !1 wherever !1 appears in the macro body. V2 and V3 are substituted
for !2 wherever !2 appears in the macro body. The macro body in this example is the
FREQUENCIES command.
Keyword Arguments
Keyword arguments are called with user-defined keywords that can be specified in any order.
In the macro body, the argument name is preceded by an exclamation point. On the macro
call, the argument is specified without the exclamation point.
• Keyword argument definitions contain the argument name, an equals sign, and the
!TOKENS, !ENCLOSE, !CHAREND, or !CMDEND keyword (see “Assigning Tokens to
Arguments” on p. 447).
• Argument names are limited to seven characters and cannot match the character portion
of a macro keyword, such as DEFINE, TOKENS, CHAREND, and so forth. See the syntax
chart on p. 440 for a list of macro keywords for the program.
• The keyword !POSITIONAL cannot be used in keyword argument definitions.
• Keyword arguments do not have to be called in the order they were defined.
Example
DATA LIST FILE=MAC / V1 1-2 V2 4-5 V3 7-8.
* Macro definition.
DEFINE macdef2 (arg1 = !TOKENS(1)
/arg2 = !TOKENS(1)
/arg3 = !TOKENS(1))
frequencies variables = !arg1 !arg2 !arg3.
!ENDDEFINE.
* Macro call.
macdef2 arg1=V1 arg2=V2 arg3=V3.
macdef2 arg3=V3 arg1=V1 arg2=V2.