SPSS® 12.0 Command Syntax Reference

422 DATA LIST
Example
* Concatenate three raw data files.
INPUT PROGRAM.
NUMERIC #EOF1 TO #EOF3. /*These will be used as the END variables.
DO IF #EOF1 & #EOF2 & #EOF3.
+ END FILE.
ELSE IF #EOF1 & #EOF2.
+ DATA LIST FILE=THREE END=#EOF3 NOTABLE / NAME 1-20(A)
AGE 25-26 SEX 29(A).
+ DO IF NOT #EOF3.
+ END CASE.
+ END IF.
ELSE IF #EOF1.
+ DATA LIST FILE=TWO END=#EOF2 NOTABLE / NAME 1-20(A)
AGE 21-22 SEX 24(A).
+ DO IF NOT #EOF2.
+ END CASE.
+ END IF.
ELSE.
+ DATA LIST FILE=ONE END=#EOF1 NOTABLE /1 NAME 1-20(A)
AGE 21-22 SEX 24 (A).
+ DO IF NOT #EOF1.
+ END CASE.
+ END IF.
END IF.
END INPUT PROGRAM.
REPORT FORMAT AUTOMATIC LIST /VARS=NAME AGE SEX.
• The input program contains a DO IF—ELSE IF—END IF structure.
• Scratch variables are used on each END subcommand so the value will not be reinitialized
to the system-missing value after each case is built.
• Three data files are read, two of which contain data in the same format. The third requires
a slightly different format for the data items. All three DATA LIST commands are placed
within the DO IF structure.
• END CASE builds cases from each record of the three files. END FILE is used to trigger
end-of-file processing once all data records have been read.
• This application can also be handled by creating three separate SPSS-format data files
and using ADD FILES to put them together. The advantage of using the input program is
that additional files are not required to store the separate data files prior to performing
ADD FILES.
Variable Definition
The variable definition portion of DATA LIST assigns names and formats to the variables in
the data. Depending on the format of the file, you may also need to specify record and
column location. The following sections describe variable names, location, and formats.