SPSS® 12.0 Command Syntax Reference

1434 REREAD
FILE Subcommand
FILE specifies an external raw data file from which the next DATA LIST command reads data.
• The default file is the file specified on the immediately preceding DATA LIST command.
• If the file specified on FILE is not the default file, the same file must be specified on the
next DATA LIST. Otherwise, the FILE subcommand is ignored and the DATA LIST command
reads the next record from the file specified on it or, if no file is specified, from the file
specified on the previous DATA LIST command.
Example
INPUT PROGRAM.
DATA LIST FILE=UPDATE END=#EOF NOTABLE
/#ID 1-3. /*Get rep ID in new sales file.
DATA LIST FILE = SALESREP NOTABLE
/ID 1-3 SALES 4-11(F,2)
NEWSALE 12-19(F,2). /*Get rep record from master file.
LOOP IF #EOF OR (#ID GT ID). /*If UPDATE ends or no new sales made.
+ COMPUTE NEWSALE = 0. /*Set NEWSALE to 0
+ END CASE. /*Build a case.
+ DATA LIST FILE = SALESREP NOTABLE
/ID 1-3 SALES 4-11(F,2)
NEWSALE 12-19(F,2). /*Continue reading masterfile.
END LOOP
DO IF NOT #EOF. /*If new sales made.
+ REREAD FILE=UPDATE COLUMN = 4. /*Read new sales from UPDATE.
+ DATA LIST FILE=UPDATE
/NEWSALE 1-8(F,2).
+ COMPUTE SALES=SALES+NEWSALE. /*Update master file.
END IF.
END CASE. /*Build a case.
END INPUT PROGRAM.
LIST.
• This example uses REREAD to merge two raw data files (SALESREP and UPDATE).
• Both files are sorted by sales representative ID number. The UPDATE file contains
only records for sales representatives who have made new sales, with variables ID and
NEWSALE. The master file SALESREP contains records for all sales representatives,
with variables SALES (which contains year-to-date sales) and NEWSALE (which
contains the update values each time the file is updated).
• If a sales representative has made no new sales, there is no matching ID in the UPDATE
file. When UPDATE is exhausted or when the ID’s in the two files do not match, the loop
structure causes the program to build a case with NEWSALE equal to 0 and then continue
reading the master file.
• When the ID’s match (and the UPDATE file is not yet exhausted), the REREAD command
is executed. The following DATA LIST rereads the record in UPDATE that matches the ID
variable. NEWSALE is read from the UPDATE file starting from column 4 and SALES is
updated. Note that the following DATA LIST specifies the same file.