Schaltungstechnik

2.2 Vorgehensweise bei der Schaltungsanalyse 79
ßen Cj, vr und qc stellen eine „free“ Quantity dar. Mit „if“ Abfragen wird das
Verhalten der Diode abhängig von verschiedenen Bereichen definiert. Das Modell
enthält alle im Bild 2.2-29 skizzierten Eigenschaften mit Bahnwiderstand, idealtypischem
Verhalten des pn-Übergangs, realem Sperrstrom, Durchbrucheffekt,
Sperrschichtkapazität und Speicherverhalten. Das Beispiel zeigt deutlich, dass sich
mit VHDL-AMS anwendungsspezifische Modelle leicht formulieren lassen.
library IEEE, DISCIPLINES;
use IEEE.math_real.all;
use DISCIPLINES.electromagnetic_system.all;
use DISCIPLINES.thermal_system.all;
use DISCIPLINES.physical_constants.all;
entity Diode is
generic ( iss, n, rs, isr, nr : real;
Cj0, Vj, M, Fc, tt : real;
bv, ibv, nbv : real;
eg, xti, temp, af, kf : real);
port (terminal anode, cathode : electrical);
end entity Diode;
architecture level1 of Diode is
terminal node : electrical;
constant vt : real := temp * physical_K / physical_Q;
quantity Cj, vr : real;
quantity vd across ic, id through node to cathode;
quantity v across ir through anode to node;
quantity qc : charge;
begin
junction_capacitance : if (vd >= (Fc*Vj)) use
Cj == Cj0/((1.0-Fc)**(1.0+M))*(1.0-Fc*(1.0+M)+M*vd/Vj);
else Cj == Cj0*(1.0 - vd/Vj)**(-1.0*M);
end use junction_capacitance;
vr == ir * rs; vd == v - vr;
if (vd >= 0.0) use
id == iss*(exp((vd)/(n*vt))-1.0);
elsif (vd < 0.0) and (vd > -1.0*bv) use
id == iss*(exp((vd)/(n*vt))-1.0)+isr*(exp(vd/(nr*vt))-1.0);
elsif (vd = -1.0*bv) use
id == -1.0*ibv;
else id == -1.0*ibv*(exp(-1.0*(vd+bv)/(nbv*vt))-1.0);
end use;
if vd < vj use
qc == tt*id - Cj*((vd-vj)*(-1.0*vj/(vd-vj))**M/(M-1.0));
else
qc == tt*id;
end use;
ic == qc'dot;
end architecture level1;
Bild 2.2-46: Verhaltensmodell einer Diode dargestellt mit VHDL-AMS