6. Funktionseinheiten eines Computers / Mikrocomputers

Rechnergrundlagen Teil 2 - 34 - Prof. Dipl.-Ing. Komar
Nachfolgendes Beispiel erzeugt eine lauffähige COM -Datei zur Abfrage der DOS-Versionsnummer.
A CS:100
;__________________________________________________________
; Beispiel zur Assemblierung mit dem DOS-Debugger aus einer Textdatei.
; Aufruf: DEBUG < VERSION.ASM > VERSION.LST
; In der Datei VERSION.LST werden alle Meldungen (auch Fehlermeldungen) des Debuggers abgelegt.
; Die lauffähige COM-Datei findet sich in VERSION .COM
;___________________________________________________________
; Assembliere den Programmcode ab CS:100
ORG 100 ;diese Assembleranweisung ist hier eigentlich überflüssig
; durch A CS:100
MOV DX, 0200 ; lade Adresse String 1
MOV AH, 09 ; Ausgabe des Textes
INT 21 ; per INT 21
;
MOV AH, 30 ; Abfrage der DOS-Version
INT 21 ;
;
PUSH AX ; Zwischenspeichern auf dem Stapel
;
MOV DL, 30 ; Convert Main Nr.
ADD DL,AL ;
MOV AH, 02 ; Ausgabe Character
INT 21 ;
;
MOV DL, 2E ; write “.“
INT 21 ;
;
POP AX ; vom Stapel zurückholen
;
MOV AL,AH ; untergeordnete Versionsnummer
MOV AH, 0 ;in ungepackte BCD-Ziffer in AH wandeln
AAM
MOV DL, 30 ; Convert Second Nr.
ADD DL,AH ;
MOV AH, 02
INT 21 ; write char.
;
MOV DX, 0220 ; lade Adr. String 2
MOV AH, 09 ; Ausgabe CR, LF
INT 21 ; per INT 21
;
MOV AX, 4C00 ; Terminate Process normal
INT 21 ; Programmbeendigung und Rückkehr nach DOS
; ; Ende des Programmcodes
ORG 200 ; Assembliere die Text-Konstanten ab CS:200, diese Anweisung erzeugt keinen Maschinencode
DB "MS -DOS Version $"
ORG 220 ; mit CR (Carriage Return = 0D h ) und LF (Line Feed = 0A h ) wird der Cursor auf den
DB 0A, 0D,"$" ; Anfang der nächsten Zeile positioniert
; speichere den Code in der Datei VERSION.COM mit den Debug-Befehlen N(ame) und W(rite)
; hier muß eine Leerzeile folgen !!! damit der Debug-Assembler-Mode beendet wird
N VERSION.COM
R BX
0
R CX
200
W CS:100
Q
Listing : VERSION.ASM