Musterlösungen zum 6.¨Ubungsblatt

Institut für Technische Informatik (ITEC)
Institut für Anthropomatik (IFA)
Rechnerorganisation im Sommersemester 2011
Musterlösungen zum 6. Übungsblatt
Lösung 1
1. Registerinhalte:
Register Inhalt
$t1 $t1 = 0x0000 0008
$t2 $t2 = 0x0000 000C
$t3 $t3 = 0x0000 0010
$t4 $t4 = 0x0000 0013
2. MIPS-Code zur Speicherung der Adresse von vec im Register $s0:
la $s0, vec
3. Programmschleife zur Ausgabe der ersten fünf Elemente aus vec:
.data
vec: .word 8, 12, 16, 19, 2002, 0, 0, 0, 0, 0
leer: .asciiz " "
.text
Prof. Dr. J. Henkel
Dr.-Ing. T. Asfour
Dipl.-Inform. Ö. Terlemez
Dipl.-Inform. M. Kröhnert
Adenauerring 2, Geb. 50.20
Email: ti@ira.uka.de
Web: http://ti.ira.uka.de
la $s0, vec # Adresse von vec in $a0
addi $t0, $0, 0 # Zaehler = 0
addi $t1, $0, 5 # zum Beenden der Schleife
add $t2, $0, $s0
loop: lw $a0, 0($t2) # Element aus vec in $a0 laden
li $v0, 1 # print_int
syscall
la $a0, leer
li $v0, 4 # print-str (Leerzeichen)
syscall
addi $t0, $t0, 1 # Zaehler inkrementieren
addi $t2, $t2, 4 # Zeiger auf vec inkrementieren
bne $t0, $t1, loop

Musterlösungen zum 6. Übungsblatt zur Vorlesung ” Rechnerorganisation“ im Sommersemester 20112
Lösung 2
# Berechnung der Quadratwurzel
.data
cr_string: .asciiz "\n" # Sonderzeichen "neue Zeile"
eingabe_str: .asciiz "Bitte geben Sie eine positive Integer-Zahl ein: "
result_str: .asciiz "Ergebnis = "
.text
# Prozedur: Ausgabe eine Integer-Zahl mit CR
print_int: li $v0, 1 # print_int
syscall
la $a0, cr_string
li $v0, 4 # print-str (cr_string)
syscall
jr $ra
# Prozedur: Quadratwurzel einer Integerzahl (Parameter in $a0, Ergebnis in $v0)
sqrt_int: move $t0, $a0 # Argument in $t0 sichern
label1: move $t2, $t0 # altes Ergebnis in $t2 sichern
divu $a0, $t0 # Teile $a0 durch $t0 (x_n)
mflo $t1 # Lade Quotient aus Register LO in $t2
addu $t0, $t0, $t1 # addiere Quotient zu $t0 (a / x_n)
srl $t0, $t0, 1 # halbiere $t0
bgt $t2, $t0, label1 # wenn $t2 (altes Ergebnis) > $t0, dann zu label1
move $v0, $t2 # Ergebnis in $v0 schreiben
jr $ra
# Start des Hauptprogrammes
.globl main
main: subu $sp, $sp, 8 # Stack Frame ist 8 Bytes
sw $ra, 4($sp) # Sichern der Ruecksprungadresse
sw $fp, 8($sp) # Sichern des alten Frame-Pointers
addu $fp, $sp, 8 # neuen Frame-Pointer definieren
la $a0, eingabe_str # print_str
li $v0, 4
syscall
li $v0, 5 # read_int (a einlesen)
syscall
move $a0, $v0 # a im Register $a0 speichern
jal sqrt_int # Quadratwurzel berechnen
move $s0, $v0 # Ergebnis in $s0 sichern
la $a0, result_str
li $v0, 4 # print_str (result_str)
syscall
move $a0, $s0 # Ausgabe Ergebnis
jal print_int
lw $ra, 4($sp) # Ruecksprungadresse wiederherstellen
lw $fp, 8($sp) # Frame-Pointer wiederherstellen
addu $sp, $sp, 8 # Stack-Frame loeschen
jr $ra

Musterlösungen zum 6. Übungsblatt zur Vorlesung ” Rechnerorganisation“ im Sommersemester 20113
Lösung 3
# Berechnung der ersten k Primzahlen
.data
cr_string: .asciiz "\n" # Sonderzeichen "neue Zeile"
eingabe_str: .asciiz "Anzahl zu berechnender Primzahlen: "
.text
# Prozedur: Ausgabe einer Integer-Zahl mit CR
print_int: li $v0, 1 # print_int
syscall
la $a0, cr_string
li $v0, 4 # print_str
syscall
jr $ra
# Prozedur: Quadratwurzel einer Integerzahl (Parameter in $a0, Ergebnis in $v0)
sqrt_int: move $t0, $a0 # Argument sichern
label1: move $t2, $t0 # altes Ergebnis sichern
divu $a0, $t0 # Teile $a0 durch $t0
mflo $t1 # Lade Quotient in $t2
addu $t0, $t0, $t1 # addiere Quotient zu $t0
srl $t0, $t0, 1 # Halbiere $t0
bgtu $t2, $t0, label1 # wenn $t2 (altes Ergebnis) > $t0, dann zu label1
move $v0, $t2 # Ergebnis nach $v0
jr $ra
# Start des Hauptprogrammes
.globl main
main: subu $sp, $sp, 8 # Stack Frame ist 8 Bytes
sw $ra, 4($sp) # Sichern der Ruecksprungadresse
sw $fp, 8($sp) # Sichern des alten Frame-Pointers
addu $fp, $sp, 8 # neuen Frame-Pointer definieren
la $a0, eingabe_str # Eingabeaufforderung
li $v0, 4 # print_string
syscall
li $v0, 5 # read_int (Zahl k)
syscall
sll $s5, $v0, 2 # mal 4, wegen 32-Bit Integer-Zahl
move $a0, $s5
li $v0, 9 # sbrk (4 x Groesse eingelesener Zahl)
syscall
move $s6, $v0 # Adresse des Primzahlfeldes in $s6
li $s0, 3 # zu pruefende Zahl jeweils in $s0 (n)
move $s1, $zero # $s1 Zaehler fuer gefundene Primzahlen (f)
loop1: bgeu $s1, $s5, fertig # wenn alle Primzahlen gefunden, dann zu fertig
addu $s7, $s6, $s1 # Adresse fuer aktuelles Element in $s7 speichern ($s6 + Zaehler)
sw $s0, ($s7) # gefundene Primzahl an Speicherstelle $s7 schreiben
move $a0, $s0
jal print_int # Ausgabe der Primzahl
addu $s1, $s1, 4 # Zaehler fuer gefundene Primzahlen erhoehen

Musterlösungen zum 6. Übungsblatt zur Vorlesung ” Rechnerorganisation“ im Sommersemester 20114
loop3: addu $s0, $s0, 2 # naechste zu pruefende ungerade Zahl in $s0 (n)
move $a0, $s0
jal sqrt_int # Quadratwurzel von $s0 (n) berechnen
move $s3, $v0 # Quadratwurzel in $s3 sichern
move $s2, $0 # Zaehler fuer zu pruefenden Dividenden := 0
loop2: addu $s7, $s6, $s2
lw $s4, ($s7) # Dividenden laden
bgtu $s4, $s3, loop1 # wenn Dividend > sqrt($s0), dann zu loop1
addu $s2, $s2, 4 # Zaehler fuer zu pruefende Dividenden erhoehen
div $s0, $s4 # $s0 / $s4
mfhi $s4 # Rest von $s0 / $s4 in $s4 speichern
beqz $s4, loop3 # wenn $s4 = 0 (teilbar), dann zu loop3
b loop2
fertig: lw $ra, 4($sp) # Ruecksprungadresse wiederherstellen
lw $fp, 8($sp) # Frame-Pointer wiederherstellen
addu $sp, $sp, 8 # Stack-Frame loeschen
jr $ra